Voit itse lisätä ja muuttaa sisältöä muokkaa-painikkeiden avulla

Ennen tallennusta suositellaan ottamaan kopio muokkausruudusta (ctrl-a -> ctrl-c)

 Olet itse vastuussa tämän teoksen käytöstä aiheutuvista vahingoista Lue lisää.

Microsoft Excel

Wikikko - kansan taitopankkista
Siirry navigaatioon Siirry hakuun

Johdanto[muokkaa]

Ks. myös sivu Microsoft 365
Visual Basic for Applications (VBA)
HUOM! Jos kaavat eivät toimi: kokeile korvata kaavassa pilkku (,) puolipisteellä (;) tai päinvastoin

Excelin kieli[muokkaa]

  • macOS Excelin kielin eli ulkoasu ja kaavat ovat käyttöjärjestelmän kielen mukaan. Seuraavalla komennolla Excelin kieli voidaan muuttaa halutuksi ilman, että macOS-käyttöjärjestelmän kieltä tarvitsee muuttaa. Komento annetaan Pääte-ohjelmassa. Seuraavassa fi-FI muuttaa kielen suomen kielelle. Etsi tarvittava maa- ja kielikoodi verkosta.
defaults write com.microsoft.Excel AppleLanguages '("fi-FI")'

Aika[muokkaa]

  • h näyttää kellonajan muodossa 6:35 ja hh muodossa 06:35
  • Laskettaessa kellonaikoja yhteen, Excel lisää aina 24 tunnin ylittyessä yhden päivän kellonaikaan. Se saadaan näkyviin lisäämällä solun formaattiin d -kirjain, esim d [hh]:mm Esim. päivän arvo on 0 kun ensimmäinen arvon on alle vuorokauden, kun ensimmäinen vuorokausi ylittyy, d-arvoksi tulee 1. Kukin aika on muunnettavissa desimaaleiksi, tällöin suurin desimaali on se, jossa on eniten päiviä ja tunteja.
    • Kun vuorokauden kellonajoista etsitään vuorokauden myöhäisintä aikaa =MAX(A1:E1) -funktiolla tai aikaisinta aikaa =MIN(A1:E1), Excel ottaa huomioon kellonaikoihin "piilossa" sisältyvät päivät. Tällöin vain saman vuorokauden ajat ovat suoraan vertailukelpoisia. Näin ollen näkyvä aika esim. 7:30 saattaa olla myöhäisempi kuin 21:30, jos kyseinen 7:30 sisältää enemmän päiviä. Tällöin kellonajat "tyhjennetään" päivistä ensin kaavalla =A1-INT(A1) eli joudutaan lisäämään uusi rivi. Tämän jälkeen kyseiseltä riviltä etsitään myöhäisin/aikaisin kellonaika. Voidaan käyttää myös =DATE - INT(DATE)
  • [h]: Käytettäessä hakasulkeita, kellonaika ilmoitetaan sisältäen yhteenlasketun yli 24 tunnin ajan. Esim. kun hh:mm näyttää 11:30, se voi tarkoittaa ensimmäisen vuorokauden 11:30 tai vaikka 2. vuorokauden 11:30. Tällöin [h]:mm näyttää ensimmäisen vuorokauden 11:30 ja 2. vuorokauden 11:30 muodossa 35:30. Eli 11:30 + 24:00 tuntia.
https://www.ablebits.com/office-addins-blog/show-time-over-24-hours-excel
https://www.ablebits.com/office-addins-blog/excel-time-format
  • Kellonaika desimaaleiksi
  1. =TUNNIT(A1)+MINUUTIT(A1)/60
  2. Muunna solun muodoksi "Yleinen/General" tai "Luku" ja vähennä desimaalit esimerkiksi kahteen.
  • Negatiiviset kellonajat: Vähennettäessä esimerkiksi 15:00 - 22:00 saadaan #####
    • Kerro vähennyslasku luvulla 24. Esim. =(A1-A2)*24 ja vaihda solun formaatiksi Number.
    • Kun kellonaikojen vähentäminen voi olla positiivinen tai negatiivinen luku: Aseta solun formaatiksi Number. Seuraavalla komennolla testataan ensin onko suurin alueella A1:E1 oleva luku suurempi kuin mistä se vähennetään. Jos luku on suurempi, suoritetaan negatiivisen kellonajan laskenta. Jos luku on pienempi, suoritetaan positiivisen kellonajan laskenta. Negatiivisen luvun osalta noudatetaan solun formaattia Number, mutta positiivisen luvun osalta käytetään TEXT-funktiota ja määritellään esitysmuodoksi H:MM.
=IF(MAX(A1:E1)>B1;(B1-MAX(A1:E1))*24;TEXT(B1-MAX(A1:E1);"H:MM"))
  • Kellonaika 10:55:30 --> 10.55.30
  1. Kopioi kellonajata Muistio-sovellukseen, muunna etsi/korvaa-toiminnolla kaksoispiste pisteeksi. Kopioi takaisin samaan kohtaan Excelissä.
  2. Aseta kellonaikasolujen luokaksi 'Aika', esim. 13.30.55
  • Kellonaikojen keskiarvo
    • Jos keskiarvoa ei ilmesty, esim. 0.23.57, on todennäköisesti kellonaikasolujen luokka väärin.
  1. Aseta kellonaikasolujen luokaksi 'Aika', esim. 13.30.55
  2. =KESKIARVO(A1:A10)
  • Kellonaikojen laskeminen yhteen, esimerkiksi tuntien 3.00.00 ja 4.00.00 on 7:00 TAI 3:00 ja 4:00 on 7:00
  1. Yhteenlaskevaan soluun =SUMMA(A1:A2)
  2. Muotoile solua joka laskee yhteen valitsemalla 'Oma' ja aseta lajiksi [t]:mm;@ tai englannin kielisessä Excelissä [h]:mm;@

Emoji[muokkaa]

  • macOS Excel:

Katso descimaal (Dec) oheisesta taulukosta: https://www.w3schools.com/charsets/ref_emoji.asp 

=UNICHAR(128151)

F2[muokkaa]

F2-näppäin saa Windowsissa solun muokattavaksi, vastaava näppäin MacOS on Ctrl-u

Haku[muokkaa]

Kaksi hakukriteeriä ja rivin näyttäminen[muokkaa]

Seuraavassa on kaavoja, joilla voidaan etsiä kahdella hakuehdolla sarakkeista ja haun täyttyessä näytetään kyseinen rivi.

  • Vaihtoehto 1

Tämä on toimiva hyvin toimiva vaihtoehto kun yksi hakuehdoista on suurimman luvun hakeminen. Tässä haetaan kahdella hakuehdolla, joista toinen on määrätty solun sisältö (A1) ja toinen sarakkeessa B oleva suurin lukuarvo. Ts. kaava hakee kaikki A1-solussa määritellyn sanan sisältävät rivit ja sen jälkeen vertaa niitä hakien rivin, jossa B-sarakkeessa on suurin lukuarvo. Kaavaa on käytetty tilanteessa, jossa on taulukko sekaisin lokitiedoista, joilla jokaisella lokitiedolla on nimi, päivämäärä, kellonaika ja muita tietorivejä. Päivämäärä ja kellonaikan on muutettu lukusarjaksi ja lukusarjasta haetaan suurin lukema, joka on lähinnä nykyhetkeä.

  • Kaavassa on virheen siistivä ominaisuus JOSVIRHE(;" ")
  • $-merkit mahdollistavat kaavan kopioinnin, jolloin vain A1 muuttuu.
  • TAULUKKO! hakee TAULUKKO-välilehdeltä eli ei ole tarpeellinen haettaessa samalta välilehdeltä.
  • Sarakkeet, jotka näytetään määritellään B1:D10
  • Suurimman lukuarvon hakeminen, joka täsmää samalla A-sarakkeen hakuehdon kanssa, määritellään kahdessa kohtaa kaavaa: $B$1:$B$10
  • Haettava solun arvo annetaan kohdassa A1. Voi olla myös heittomerkeissä esim. "arvo"
  • Haettavan solun hakualue määritetään kohdassa $A$1:$A$10
  • Englannin kieliset komennot ovat IFERROR, INDEX, MATCH, MAXIFS
=JOSVIRHE(INDEKSI(TAULUKKO!$B$1:$D$10;VASTINE(MAKS.JOS.JOUKKO(TAULUKKO!$B$1:$B$10;TAULUKKO!$A$1:$A$10;A1);TAULUKKO!$B$1:$B$10;0);0);" ")
  • Vaihtoehto 2

Tässä kaavassa tulostetaan rivi, joka on merkitty x-kirjaimella sarakkeessa A ja toisena hakuehtona sisältää määrätyn sanan.

  • Kaavassa on virheen siistivä ominaisuus JOSVIRHE(varsinainen kaava;" ")
  • Sarakkeet, jotka näytetään määritellään B1:D10
  • Täsmäävä X-ehto määrätään "X", mutta se voi olla myös esimerkiksi solu, kuten A1=A1:A10
  • X-ehdollista riviä haetaan alueelta A1:A10
  • Haettava solun arvon annetaan kohdassa B1
  • Haettavan solun hakualue määritetään kohdassa B1:B10
  • Hakuehtoija voi olla useita, ne erotetaan *-merkillä esim. (ehto1)*(ehtoa2)*(ehto3)
  • Englannin kieliset komennot ovat IFERROR, INDEX, MATCH
=JOSVIRHE(INDEKSI(B1:D10;VASTINE(1;("X"=A1:A10)*(B1=B1:B10);0);0);" ")

Yksi hakukriteeri ja yhden solun näyttäminen[muokkaa]

  • Vaihtoehto 1

Tässä kaavassa haetaan riviä, joka on merkitty x-kirjaimella sarakkeessa A ja sen jälkeen näytetään kyseisen rivin sarakkeen C arvo.

  • Kaavassa on virheen siistivä ominaisuus JOSVIRHE(varsinainen kaava;"-") eli kun millään rivillä ei ole x-kirjainta, näytetään -
  • TAULUKKO! hakee TAULUKKO-välilehdeltä eli ei ole tarpeellinen haettaessa samalta välilehdeltä.
  • $-merkit mahdollistavat kaavan kopioinnin, jolloin hakualue ei muutu ja tarvitsee muuttaa vain sarakenumero.
  • Hakualue A1:D10 eli sisältää sekä sarakkeen missä X-kirjain ja myös tuotavan sarakkeen.
  • Tuotava sarake määritellään numerolla, tässä 3. Sarake A on 1, sarake B on 2 jne.
=JOSVIRHE(PHAKU("x";TAULUKKO!$A$1:$D$10;3;EPÄTOSI);"-")

HTML-tiedoston tuonti[muokkaa]

  1. Tallennetaan selaimesta sivun lähdekoodi html-tiedostopäätteellä.
  2. Data > Get Data > From HTML > valitaan tiedosto
  3. Tiedosto tallentuu välilehdelle, johon voidaan kohdistaa nyt esimerkiksi hakutoimintoja toiselta välilehdeltä ja siirtää tietoa muuhun käyttöön.

#JAKO/0![muokkaa]

=A1/A2 antaa #JAKO/0!
=JOS(A2;A1/A2;0)

Jos (If)[muokkaa]

  • Kaava
=JOS(A1=10 ; mitä tehdään kun totta ; mitä tehdään kun ei totta)
=JOS(A1=10;"Luku on 10";)
=JOS(A1=10;"Luku on 10";"Luku ei ole 10")
=JOS(A1=10;"Luku on 10";JOS(A1=20;"Luku on 20";))
=JOS(JA(A1=TOSI;B1=TOSI);"A1 ja B1 -solut ovat kummatkin tosia";"A1 tai B1 tai ei kumatkaan ole tosia")
=JOS(TAI(A1=TOSI;B1=TOSI);"A1 tai B1 -solu on tosi";)
  • Laske rivien lukumäärä, kun useamman sarakkeen ehdot täyttyvät
    • Oheinen kaava laskee määrätyltä ajanjaksolta ne rivit, joissa on lisäksi sana SARI. Aseta soluun K1 alkupäivämäärä esim. 1.1.2022 ja K2 päättymispäivämäärä esim. 31.12.2022. Sarakkeessa A on päivämää. Sarakkeessa B SARI tai muu teksti.
=LASKE.JOS.JOUKKO(A:A;">="&K1;A:A;"<="&K2;B:B;"="&"SARI")

Kaksoiskappaleiden poistaminen[muokkaa]

  • Poistossa jää jäljelle rivi, joka on rivinumeroltaan pienempi kaksoiskappaleista.
  1. Jos on yhdistetty esim. taulukko A ja taulukko B, joissa on esimerkiksi sarakkeessa A1 samoja yritysten nimiä. Kuitenkin taulukon A rivit halutaan jättää jos siitä löytyy kaksoiskappale taulukosta B.
    1. Järjestä tällöin taulukko A ylimmäiseksi (lähempänä 1-riviä) ja taulukko B sen jälkeen.
  2. Valitse värjäämällä kaikki / käsiteltävät rivit
  3. Valitse Data > Remove Duplicates
    1. Poista merkintä kohdasta Select All
    2. Valitse sarake, jossa kaksoiskappaleita verrataan > Ok

Kaksoiskappaleiden korostus[muokkaa]

  1. Valitse värjäämällä sarakkeet/rivit/solut joissa korostus tehdään
  2. Home > Conditional Formatting > Highlight Cell Rules > Duplicate Values...
    1. Style: Classic, Format only unique or duplicate values, duplicate values in the selected range, Format with Light Red Fill with Dark Red Text > Ok

Kehitystyökalut[muokkaa]

  1. Tiedosto > Asetukset > Valintanauhan mukauttaminen > valitse Kehitystyökalut > OK
  2. Kehitystyökalut-valikko ilmestyy näkyville ikkunan yläosaan.

TAI Jos välilehdistä ei löydy kohtaa 'Kehitystyökalut': Klikkaa ikonitoimintorivillä hiiren oikeaa > Mukauta valintanauhaa... > Valitse Kehitystyökalut

Keskiarvo[muokkaa]

Keskiarvo määrätyltä ajanjaksolta. Ensimmäisenä määritellään alue mistä keskiarvo lasketaan ja sen jälkeen ehdot mitkä rivit otetaan mukaan kyseiseltä alueelta. Seuraavassa solussa D1 on määritelty vuosi ja C1 solussa kuukausi. Tämän jälkeen otetaan huomioon kaikki kuukauden päivät välillä 1 - 31. Sarakkeessa A on päivämäärät. Sarakkeessa B ovat luvut, joiden keskiarvo lasketaan. =JOSVIRHE(KESKIARVO.JOS.JOUKKO(Välilehtinimi!$B$1:$B$10;Välilehtinimi!$A$1:$A$10;">="&PÄIVÄYS($D$1;$C1;1);Välilehtinimi!$A$1:$A$10;"<="&PÄIVÄYS($D$1;$C1;31));0)

Kieli[muokkaa]

  • MacOS-käyttöjärjestelmässä Excel noudataa ulkoasussa tietokoneen kieliasetusta. Tiedostokohtaisesti kieli voidaan muuttaa Tools > Language...
  • MacOS antaa mahdollisuuden myös muuttaa ohjelmakohtaisesti kieliasetusta. Esim. jos käyttää tietokonetta normaalisti esim. suomeksi ja haluaa Excelin olevan englanninkielinen ulkoasultaan: System Preferences > Language & Region > Apps > + > Application: Microsoft Excel.app > Language: English > uudelleenkäynnistetään Excel.

Kirjainten poistaminen ja numeroiden jättäminen[muokkaa]

Seuraava kaava poistaa solussa A1 olevasta numeroita ja kirjaimia sisältävästä tekstistä kirjaimet.

=TEXTJOIN(""; TRUE; IFERROR(MID(A1; ROW(INDIRECT( "1:"&LEN(A1))); 1) *1; ""))

Kopiointi[muokkaa]

  • Tuplaklikkaa solun kulmassa kopiointi-ristiä ja kyseinen arvo kopioituu siitä solusta alaspäin. <-- tarkenna

Korvaavia taulukkolaskentaohjelmia[muokkaa]

  • Open Office / Calc taulukkolaskenta suomenkielisenä.
  • Numbers (macOS, iOS)


Negatiivisten lukujen värjääminen[muokkaa]

Valitse alue ja avaa 'Format Cells' -> Number -> valitse punainen -1234,10 -> OK

  • Löytyy myös muita vaihtoehtoja kuten korostaminen.

Negatiivisiksi luvuiksi vaihtaminen[muokkaa]

  1. Kirjoita soluun -1
  2. Kopio em. solu
  3. Värjää solut, jotka vaihdetaan negatiivisiksi luvuiksi
  4. Valitse Paste > Paste Special... > Multiply > OK
  5. Tyhjennä solu -1

Numeroiden vaihtaminen päinvastaiseksi[muokkaa]

Kerro luku -1:llä eli esim =A1*-1

PDF-tiedoston luettelon tuonti Exceliin[muokkaa]

Odota, toimenpiteet voivat kestää ja näkyä sillä aikaa "Ei vastaa..."

  1. Värjää tuotava luettelo PDF-asiakirjassa hiirellä tai ctrl-a ja kopioi (ctrl-c)
  2. Avaa Word-dokumentti ja liitä kopio (ctrl-v)
    1. Voit muotoilla tekstiä, riveiksi, jotka on erotettu rivinvaihdolla.
    2. Luettelon tekstit voivat olla erotettuna esimerkiksi välilyönnillä.
    3. Valitse koko teksti (ctrl-a) > Lisää > Taulukko > Muunna teksti taulukoksi... > ponnahdusikkunassa 'Tekstin erotin' valitse 'Muu' kohtaan välilyönti eli tee välilyönti ruutuun > OK
    4. Muodostunut taulukko on valittuna > kopioi ctrl-v
  3. Avaa Excel-dokumentti ja liitä kopio (ctrl-v)

Pienin arvo[muokkaa]

  • Etsitään alueen pienin arvo, joka on suurempi kuin nolla
    • =SMALL(A1:A1000,COUNTIF(A1:A1000,0)+1)


Postinumero[muokkaa]

Postinumerosarakkeesta häviävät etunollat. Sarakkeen solujen muoto täytyy muuttaa: Valitse postinumerosarake painamalla koko sarake ylhäältä painaen / paina hiiren oikeaa näppäint ja valitse sieltä Format Cells... / Number -välilehti / Category Special / Zip Code.

Prosenttilaskut[muokkaa]

  • Kuinka monta prosenttia solujen arvot ovat yhteensä kaikista alueen soluista. Esim. 15 solua on 1500 % ja kun yhdessä solussa on arvo 50, tulos on 3,33 %.
    • =SUMMA(A1:A15)/(RIVIT(A1:A15)*100)

Pudotusvalikko[muokkaa]

  • Pudotusvalikon tekstit voidaan hakea samalta välilehdeltä, toiselta välilehdeltä tai toisesta tiedostosta.
  • Pudotusvalikon luettelon valintojen alle jätetään usein tyhjiä soluja täydennettäväksi uusilla valinnoilla. Tällöin pudotusvalikkoa käytetettäessä luettelo ei välttämättä aukeudu Excelin työpöytäversioissa ylimmästä. Pikakorjaus on, että luettelon ylimmäksi jättää yhden tyhjän solun.
  • Luettelo toisella välilehdellä olevasta luettelosta:
  1. Tehdään luettelo allekkain sarakkeeseen A.
    1. Valitse luettelon solut ja paina ctrl+T, jolloin luetteloista muodostuu taulukko, jonka hyöty on se, että kun taulukkoon lisää kohteita, pudotusvalikot päivittyvät automaattisesti. Tätäkin ilman pudotusvalikko myös kuitenkin toimii.
  2. Valitaan pudotusvalikolle solu johon se lisätään > Data(Tiedot)-välilehti > Data Validation (Tietojen kelpoisuuden tarkistaminen) > Allow: List > Source: valitaan luettelo esim. =Välilehdennimi!A1:A10 > ok
    1. 'Ignore blank': valinta sallii jättää valinnan tyhjäksi.
    2. 'Input Message': viesti klikattaessa solua.
    3. 'Error Alert': viesti virhevalinnasta.
  • Eri pudotusvalikon teksti kuin valittaessa näkyvä teksti
  1. Kehitystyökalut > Lisää > ActiveX-komponentit > Yhdistelmäruutu (Combobox) > vedä painike haluttuun kohtaan hiirellä
  2. Kehitystyökalut > Suunnittelutila
  3. Paina hiiren oikeaa pudotusvalikon päällä > Ominaisuudet
    1. BoundColumn: 2
    2. ColumnCount: 2
    3. ColumnWidths: 20 pt;0 pt tulostaa pudotusvalikossa vain sarakkeen A-tiedot
    4. LinkedCell: solu, johon teksti tulee, esim. C10
    5. ListFillRange: Lisää sarakkeet joista data haetaan, esim. Välilehdennimi!A1:B100 hakee toiselta välilehdeltä A ja B sarakkeiden tiedot, A on pudotusvalikossa näkyvä teksti ja B on tulostuva teksti.
    6. ListRows: 20 on pudotusvalikossa näkyvien valintojen lukumäärä ilman skrollausta
  4. Sulje suunnittelutila ja testaa pudotusvalikkoa
  • Kun lisäät luetteloon rivejä ne ovat välittömästi käytettävissä, jos ne vain sisältyvät ListFillRange-alueeseen.
  • Huomaa, että ActiveX-komponentteja pääsee muokkaamaan vasta kun valitsee 'Suunnittelutila' <--tarkenna
  • Kaavallisia tekstejä ei voine kopioida <-- tarkenna

Pudotusvalikko-valintojen hakeminen toisesta tiedostosta[muokkaa]

Esimerkiksi halutaan tehdä eri asiakkaista oma excel-taulukko, jossa lomakkeen täyttövaihtoehdot ovat yhteneväisiä. Täyttövaihtoehdot voivat myöhemmin muuttua. Tällöin voi luoda yhden "master-taulukon", josta haetaan aina ajantasaiset pudotusvalikkovaihtoehdot.

  1. Luodaan excel-tiedosto, esim. nimeltään Jokutiedosto, johon tulee pudotusvalikkojen valinnat. Esim. 1-riville otsikot ja sarakkeisiin niiden alle pudotusvalikoiden valinnat.
    1. Insert (Lisää) > Name > Define Name > annetaan esim. sarakkeen otsikon nimi: jokunimi > valitaan pudotusvalikoiden tulevat valinnat > ok (jos työkaluriviä ei ole Windowsin ruudun yläreunassa, kirjoita "Kerro, mitä haluat tehdä... -kohtaan: Nimien hallinta)
  2. Luodaan excel-tiedosto, johon haetaan edellä tehdystä tiedostosta valintavaihtoehdot.
    1. Insert > Name > Define Name > annetaan esim. sarakkeen otsikon nimi: jokunimi > kirjoitetaan =Jokutiedosto.xlsx!jokunimi > ok. Eli tuodaan toisesta taulukosta valikkovaihtoehdot tähän taulukkoon. Lisättäessä myöhemmin lisää, se tapahtuu ensin kirjoittamalla uusi nimi ja sitten painamalla +
    2. Valitaan pudotusvalikolle solu johon se lisätään > Data-välilehti > Data Validation > Allow: List > Source: =jokunimi > ok. Eli käytetään jokunimenä edellisessä kohdassa tässä taulukossa määriteltyä nimeä.
  3. Huom! Pudotusvalikot toimivat vain, kun valintavaihtoehtotiedosto on avattu!

Pyöristys[muokkaa]

  • Pyöristetään luvun kympit alaspäin viimeiseen tasalukuun eli 12345 --> 12340

=ROUNDDOWN(12345,-1)

Päivämäärä[muokkaa]

  • Päivämäärän muotoileminen
    • Vaihda solun muotoilua. Excelin onlineversiossa on suppeampi mahdollisuus muotoilla kuin työpöytäversiossa.
    • Kaavassa
      • Tänään 15.12.2024 (15JOULU24)
="Tänään " & TEKSTI(TÄMÄ.PÄIVÄ();"PP.KK.VVVV") & " (" & ISOT(TEKSTI(TÄMÄ.PÄIVÄ();"PPKKKVV") & ")")
  • #VALUE-virhe
    • Esimerkiksi lisättäessä päivämäärään yksi päivä =A1+1. Päivämäärän sisältävän solun (tässä A1) voi asettaa esimerkiksi muotoilu 20.5.2024, mutta syötä päivämäärä soluun seuraavasti 5/20/24 Tällöin kun kun esim. solussa B1 on kaava =A1+1, se näkyy oikein ja sen muotoilu voi olla sama 21.5.2024.
  1. Kirjoita johonkin tyhjään soluun luku 1462. Luku ei ilmeisesti ole tarkka kaikilla vuosijaksoilla ja alkuperäiseen päivämäärään verrattaessa, saattaa näin heittää.
  2. Kopioi solu (cmd/ctrl-c)
  3. Värjää solut, joissa on väärä vuosiluku eli päivämäärä
  4. Valitse Liitä > Liitä määräten... > Liitä Arvot > Laskutoimitus Lisää > OK
  • Luvusta vuosien, kuukausien ja päivien laskeminen
    • =PVMERO(0;A1;"y")&" vuotta "&PVMERO(0;A1;"ym")&" kuukautta "&PVMERO(0;A1;"md")&" päivää"
  • Kahdesta päivämäärästä vuosien, kuukausien ja päivien laskeminen
    • =PVMERO(A1;A2;"Y")&" vuotta " & PVMERO(A1;A2;"YM")&" kuukautta " & PVMERO(A1;A2;"MD")&" päivää"
      • edellisessä A1 on alkupäivämäärä ja A2 päättymispäivämäärä.
  • Päivämäärän eteen viikonpäivä 3-kirjaimisena ddd tai kokopituisena dddd: Custom > ddd dd/mm/yyyy
  • Solussa päiväyksen voi muuttaa muotoilu-kohdassa, jos näyttää päiväyksen esimerkiksi numerosarjana. Kaavassa käytä TEKSTI() ja muotoilua, ks. otsikko 'Tekstin muotoilu kaavassa'
  • Lisätään A1-solussa oleva kk-määrä tähän päivään.
      • =PÄIVÄ.KUUKAUSI(TÄMÄ.PÄIVÄ();A1)
  • Tarkistetaan onko viikonloppu solussa A1 ilmoitetussa päiväyksessä ja ilmoitetaan seuraava maanantai. Jos arki, ilmoitetaan sama päivämäärä.
    • =JOS(VIIKONPÄIVÄ(A1;2)>5;A1+(7-VIIKONPÄIVÄ(A1;2)+1);A1)
  • Päiväys ja nimimerkki sulkeissa: ="(" & TEKSTI(TÄMÄ.PÄIVÄ();"PP.K.VVVV") & " Etunimi)"
  • Lisätään 2 kuukautta solussa A1 olevaan päivämäärään: =PÄIVÄ.KUUKAUSI(A1;2)
  • Päivämäärä muuttujassa
Dim koronaPvm As Date
koronaPvm = "19.3.2020"
  • Lasketaan saman päivämäärän, joka ilmoitettu solussa C3, sisältävien rivien B-sarakkeessa olevat lukemat yhteen.
    • SUMIF(A1:A1000,C3,B1:B1000)
  • Montako kertaa määrätty päivämäärä toistuu määrätyllä alueella -kaava
  1. Päivämäärät ovat sarakkeessa A
  2. Lisää sarake B, jossa päivämäärät juoksevat alaspäin saraketta.
  3. Lisää ylimmän päivämäärän viereen sarakkeeseen C kaava: =LASKE.JOS(A1:A10;B1)
  4. Kopioi kaavaa alaspäin muiden päivämäärien viereen.
  • Montako kertaa määrätty vuoden kuukausi toistuu määrätyllä alueella -kaava
    • Seuraavassa selvitetään helmikuu 2022 -solujen lukumäärä alueella A1-A10
    • =TULOJEN.SUMMA((KUUKAUSI(A1:A10)=2)*(VUOSI(A1:A10)=2022))
  • Montako kertaa määrätty päivämäärä toistuu määrätyllä alueella --> Pivot-taulukko
  1. Valitse alue, joka sisältää päivämäärät.
  2. Lisää > Pivot-taulukko > Valitse Pivot-taulukon sijoituskohta: Uusi laskentataulukko >
  3. Muodostuu uusi välilehti
    1. Vedä hiirellä oikeassa palkissa ylhäällä olevasta ruudusta päivämäärä, Neljännesvuodet ja/tai Vuodet palkin alaosaan kohtiin Akseli (Luokat) ja Arvot.
    2. Säädä tarpeen mukaan arvoja ja miten tiedot näkyvät.
  • Päivämäärän ja kellonajan muuttaminen numerosarjaksi
    • Päivämäärä voidaan esittää numerosarjana muuttamalla solun muotoilu luvuksi.
    • Jos kuitenkin numerosarjaa halutaan käsitellä esimerkiksi verrata lukuja toisiinsa, tulee se muuttaa kokonaisluvuksi.
    • Kaavassa päivämäärä on solussa A1 muodossa pp.kk.vvvv ja kellonaika solussa B1 muodossa tt.mm
      • HUOM! Kellonaika tulee syöttää kaksoispisteellä eikä pisteellä vaikka se näkyykin pistemuodossa - eli syöttömuoto 15:30
=KOKONAISLUKU(ARVO(A1)&TEKSTI(B1; "TTMM"))
  • Military Date Time Group
Ks. sivu Military Date Time Group.
    • 15.12.2024 23:45 näytetään muodossa 152345BJOULU24. Kirjain B osoittaa Suomen aikavyöhykettä.
    • Kuukausi pitäisi esittää kolmella kirjaimella, mutta suomenkielisessä Excelissä se tulostuu neljäkirjaimisena.
="Tulostettu "& ISOT(TEKSTI(NYT();"PPTTMM\BKKKVV"))

Rasti ruutuun[muokkaa]

  • Excel for Mac (2016):
  1. Excel > Preferences > View > In Ribbon, Show Developer tab
  2. Developer tab > Check Box

Rivien piilottaminen[muokkaa]

  1. Tiedot-välilehti > valitse Suodata, sarakkeisiin ilmestyy pienet nuoli-ikonit.
  2. Klikkaa haluamasi sarakkeen nuoli-ikonia > valitse sen sarakkeen arvot, jotka rivit haluat näkyvän > Ok. Tai vaihtoehtoisesti käytä muita suodatusvaihtoehtoja.
  3. Päivitä tarvittaessa avaamalla edellinen valikko ja ok.

Rivien poistaminen jotka sisältävät määrätyn tekstin[muokkaa]

  1. Asetetaan suodatus päälle: Home > Sort&Filter > Filter
  2. Etsittävää tekstiä sisältävän sarakkeen yläkulmasta avataan pudotusvalikko
    1. Filter: Choose One > Contains > lisätään etsittävä teksti -> ilmestyy vain rivit joissa kyseinen teksti
    2. Poistetaan rivit: valitaan rivit > Home > Delete > Delete Sheet Rows
    3. Tyhjennetään suodatin: Etsittävää tekstiä sisältävän sarakkeen yläkulmasta avataan pudotusvalikko > Clear Filter

Rivien vaihteleva väri[muokkaa]

  1. Valitse alue
    1. Alueita voi myös valita samalle kaavalle puolipisteellä eroteltuna esim. A1:A10;B50:B60
  2. Valitse Ehdollinen muotoilu
  3. Valitse työpöytä tai online-excelissä kohta, missä lisätään kaava. Numero 1 värjää parittomat ja numero 0 parilliset.
    1. =JAKOJ(RIVI(); 2) = 1
  4. Määritä taustaväri ja fontin väri
  • Kaava saattaa ajaa yli toisen ehdollisen muotoilun, jossa väritetään soluja. Aseta silloin ehto Lopeta jos tosi.
  • Jos piilotetaan nolla-arvoja ehdollisella muotoilulla asettamalla fontti taustaväriksi, ne näkyvät läpi toisella taustavärillä.

Rivinvaihto[muokkaa]

  • Alt + Enter
  • Kaavassa MERKKI(10) tai CHAR(10)
  • HUOM! Solu, jossa rivinvaihtoa käytetään, tulee olla valittunna 'Rivitä teksti'

Solu tyhjä / ei tyhjä[muokkaa]

  • =COUNTA(alue) laskee solut, jotka eivät ole tyhjiä.
  • =A1<>""
  • Jos solu ei ole tyhjä, sen voi esim. värjätä ehdollisen muotoilun avulla käyttämällä kaavaa tai oheista kaavaa voi käyttää esimerkiksi toisessa kaavassa.
  • Jos solu ei ole tyhjä, tulostetaan '- Liikevaihto' ja sen perään liikevaihdon suuruus ja rivinvaihto:
    • JOS(EI(ONTYHJÄ(Välilehdennimi!A1));"- Liikevaihto " & Välilehdennimi!A2 & " €" & MERKKI(10);)
    • Englanniksi NOT ja ISBLANK

Solujen lukumäärä[muokkaa]

  • Solujen lukumäärän laskeminen määrätyllä alueella, oli solujen sisältö mitä tahansa: =LASKE.JOS('Välilehtinimi'!A1:A10;"")

Solun koko[muokkaa]

  1. Muuta tarvittaessa mittayksikkö asetuksissa
  2. View > Page Layout (eli jos normaalisti taulukko näkyy 'Normal', muuta se 'Page Layout'
  3. Valitse solu
  4. Home > Format > 'Row Height...' ja 'Column Width...'

Solun lukitseminen[muokkaa]

Esim. (A1*$B$1) kaavaa kopioitaessa A1 muuttuu rivin mukaan, mutta B1 pysyy aina samana.

Solun valitseminen[muokkaa]

=SIIRTYMÄ(A1;0;1) '0 riviä alas ja yksi oikealle solusta A1 eli hakee solun A2 arvon (OFFSET)

Solun muotoilu[muokkaa]

  • Solun muotoilu toisen solun arvon mukaan
  1. Valitse koko sarake tai solu, joka värjätään.
  2. Ehdollinen muotoilu > Uusi sääntö > Määritä kaavan avulla, mitkä solut muotoillaan
  3. Kirjoita sen solun arvo, jota käytetään sääntönä, tässä B-sarakkeessa oleva, $B1 tarkoittaa koko saraketta: =$B1="teksti"
    1. $-merkki ennen sarakkeen kirjainta tekee sarakeviittauksesta absoluuttisen.
    2. Solun ollessa tyhjä: =$B1=""
    3. =JOS(JA(A1="";B1 > 3);TOSI;EPÄTOSI)
  4. Muotoile haluttu korostusväri tms. > OK


  • Solujen värjääminen, jotka vielä tyhjiä:
  1. Valitse värjättävät solut
  2. Conditional Formatting -painike
  3. Highlight Cells Rules > equal to > aseta arvo 0 > valitse väri

Suodatus[muokkaa]

Seuraava kaava hakee Sheet1:ltä sarakkeesta A solussa E1 määriteltyä tekstiä tms. ja listaa löydettyjen rivien sarakkeiden B ja C solujen arvot kaavan soluun ja siitä alaspäin ja oikealle. Kopioitaessa tulostuvasta taulukosta arvo, se kopioituu Excelin ulkopuolella arvona. Excelissä itsessään kopiointi tehdään arvon liittämisenä.

=FILTER(Sheet1!B:C;Sheet1!A:A="haettava teksti";"")

=SUODATA(Sheet1!B:C;Sheet1!A:A="haettava teksti";"")

Sähköpostiosoitteen erottaminen tekstistä[muokkaa]

=IFERROR(TRIM(RIGHT(SUBSTITUTE(LEFT(A1;FIND(" ";A1&" ";FIND("@";A1))-1);" ";REPT(" ";LEN(A1)));LEN(A1)));" ")
=JOSVIRHE(POISTA.VÄLIT(OIKEA(VAIHDA(VASEN(A1;ETSI(" ";A1&" ";ETSI("@";A1))-1);" ";TOISTA(" ";PITUUS(A1)));PITUUS(A1)));" ")
=IFERROR(TRIM(RIGHT(SUBSTITUTE(LEFT(A11;FIND("@";A1)-1);" ";REPT(" ";99));99))&MID(A1;FIND("@";A1);FIND(" ";A1&" ";FIND("@";A1))-FIND("@";A1));" ")

Lähteet: https://www.extendoffice.com/documents/excel/1272-excel-extract-email-address.html ja https://stackoverflow.com/questions/11243423/getting-email-address-from-a-cell-in-excel

Taulukko[muokkaa]

Excelissä määrätyissä tilanteissa kannattaa muodostaa jostain tietoa sisältävästä alueesta taulukko, jolle annetaan nimi ja tätä nimeä voidaan tällöin suoraan kutsua. Taulukon rajojen sisäpuolelle voi vapaasti lisätä lisää rivejä ja sarakkeita.

  1. Valitse taulukon solut.
  2. Paina ctrl-t
  3. Hyväksy ponnahdusvalikossa taulukon lisääminen.
  4. Valitse taulukon solut, jolloin valikkorivi muuttuu Taulukon rakenne / Table
  5. Anna taulukolle nimi (Table Name)
  6. Säädä tarvittaessa muita taulukon ominaisuuksia, kuten otsikkorivi, jolloin siihen voidaan viitata: taulukkoNimi[#Ylätunnisteet]
  • Kun taulukossa on otsikkorivi käytössä, voidaan määrätyn sarakkeen otsikkoon viitata: taulukkoNimi[otsikko]
  • Haetaan taulukosta määrättyjen sarakkeiden tiedot ja näytetään määrätty määrä rivejä, jotka täyttävät hakuehdot
  • Tarkoituksena tässä on yhdellä välilehdellä oleva taulukko, josta haetaan hakuehdot täyttäviä rivejä toiselle välilehdelle. Hakuehdot ovat ajankohdan vertaaminen nykyhetkeen ja tila on 'aurinkoinen'.
  • Kaavassa on virheen siistivä ominaisuus JOSVIRHE(;" ") joka tulostaa sanat 'ei ole', jos haku ei tuota yhtään tulosta.
  • Kaavaan liittyy yhden solun kokoisen taulukon nimeltä 'Ajankohta'. Solu sisältää kaavan =NYT() eli kyseisen taulukon päivityksen hetken päivämäärän ja ajan. Kyseisen solun muotoilu on suomalainen Aika pp.kk.vvvv tt.mm
    • Haku siis tapahtuu ainoastaan kun kyseisessä excel-tiedostossa muutetaan jonkun solun arvoa. Koska Excelin verkkoversiossa ei voida käyttää makroja (2024), voidaan esimerkiksi tehdä pudotusvalikko, jossa vaihdettaessa kahden valinnan välillä, päivittyy taulukko.
  • Kaava hakee taulukosta, joka on nimeltään taulukkoNimi. Kyseisessä taulukossa on otsikoidut sarakkeet nimi, pvm, aika, tila. Taulukon asetuksissa on valittu otsikkorivi-valinta, jolloin edellä mainittuihin voidaan viitata taulukkoNimi[#Ylätunnisteet]
  • Ensimmäinen hakuehto on ajankohta. Taulukosta yhdistetään muodossa p.k.vvvv ja tt.mm (syötetty muodossa tt:mm) annetut päivämäärät ja ajat. Kyseisten solujen muotoilut ovat suomalaisia pp.kk.vvvv ja tt.mm Sen jälkeen kyseistä yhdistelmää verrataan nykyhetkeen, joka saadaan taulukosta Ajankohta. Ajankohdan pitää olla sama tai tulevaisuudessa (>=)
  • Toinen hakuehto on 'aurinkoinen', sarakkeessa 'Tila'. Hakuehtoja voi olla useita, ne erotetaan *-merkillä esim. (ehto1) * (ehtoa2) * (ehto3)
  • Hakuehdot täyttävien näytettävien rivien määrä määritellään kaavassa kohdassa A1. Määrä voidaan laittaa lukuna suoraan kaavaan tai kuten tässä, määrä on säädettävissä solussa A1.
  • Taulukosta näytettävät sarakkeet määritellään numeroina, sarake A on 1, B on 2 jne. Tulostusjärjestys voidaan asettaa sarakenumeroiden järjestyksellä. Joten koko riviä ei tarvitse tuoda.
  • Huomioon otettavien taulukon sarakkeiden määrä määritellään kaavan kohdan A1 jälkeen. Luvun tulee olla vähintään sama kuin suurin tulostettavan sarakkeen numero! Esim. Jos tullaan näyttämään sarake numero 4 (D), tulee luvun olla vähintään 4 tai suurempi.
  • Kaava sijoitetaan siihen kohtaan jotain välilehteä, josta alkaen rivit halutaan tulostumaan alas ja oikealle. Kaava tulee vasempaan yläkulmaan. Tarvitaan siis vain yksi kaava yhteen soluun.
  • Jos tulee virheilmoitus #LEVITTYMINEN, on alueella, jossa tulokset näytetään jotain soluja, joissa on arvoja. Tyhjää tällöin riittävän kokoinen alue, että tulosteet mahtuvat alueelle.
  • Englannin kieliset komennot ovat IFERROR, CHOOSECOLS, VSTACK,TAKE, FILTER. Muuta myös sana Ylätunnisteet
=JOSVIRHE(VALITSESARAKKEET(VPINO(taulukkoNimi[#Ylätunnisteet];OTA(SUODATA(taulukkoNimi;((taulukkoNimi[Pvm] + taulukkoNimi[Aika]) >= Ajankohta) * (taulukkoNimi[Tila] = "aurinkoinen");" ");A1;4));1;2;4);"ei ole")

Teksti isoksi / pieneksi[muokkaa]

  1. Lisää muutettavan sarakkeen viereen uusi sarake, esim. B
  2. Lisää esim. sarakkeeseen B2 kaava UPPER tai LOWER: =UPPER(A2)
  3. Tuplaklikkaa sarakkeen B2 oikeaa alakulmaa ja kaava kopioituu kaikkiin B2 sarakkeen soluihin.
  4. Kopio sarakkeen B arvot leikepöydälle.
  5. Aktivoi solu A2 > Paste > Values
  6. Poista sarake B.
  • Solun tekstin ensimmäisen kirjaimen muuttaminen isoksi kirjaimeksi. Jos tekstin edessä on esim. ranskalainen viiva ja väli, vaihda numeron 1 paikalle numero, joka on vasemmalta isoksi vaihdettava kirjain:
    • =UPPER(LEFT(A1,1))&RIGHT(A1,LEN(A1)-1)

Tekstin / luvun käsittely[muokkaa]

Huom. MacOS käytä puolipistettä pilkun sijaan.

  • =RIGHT(A1; LEN(A1)-5) antaa tulokseksi 6789 kun solussa A1 on 123456789 eli näyttää oikealta kuudennesta merkistä lähtien.
  • =TRUNC(A1; 2) antaa tulokseksi 39,9 kun solussa A1 on 39,988 eli ei pyöristä.
  • =REPLACE(A1;3;1;".") antaa tulokseksi 12.456789 kun solussa A1 on 123456789 eli korvaa kolmannen merkin pisteellä.
  • =ROUND(A1;3) pyöristää kolmeen desimaaliin.
  • ="Teksti " & A1 & "teksti"
  • =ABS(A1) muuntaa negatiivisen luvunku positiiviseksi luvuksi

Tekstin jakaminen useaan soluun[muokkaa]

  • Vasemman puoleisin sana kolmesta: =LEFT(A1;SEARCH(" ";A1)-1)
  • Keskimmäinen sana kolmesta: =IFERROR(MID(A1;SEARCH(" ";A1)+1;SEARCH(" ";A1;SEARCH(" ";A1)+1)-SEARCH(" ";A1));"")
  • Oikean puoleisin sana kolmesta: =RIGHT(A1;SEARCH(" ";A1)-1)
https://trumpexcel.com/split-cells-in-excel/
http://office.microsoft.com/en-001/excel-help/split-text-into-different-cells-HA102809804.aspx
  • Eräs vaihtoehto
  1. Tee jaettavan solun oikealle puolelle sarakkeita niin monta kuin jaettavia osia tulee olemaan.
  2. Valitse sarakkeen halutut solut.
  3. Tiedot > Teksti sarakkeisiin > valitse Erotettu > Seuraava > Erottimet: Väli

Määrätyn tekstin viereisen solun tekstin noutaminen toiselta välilehdeltä[muokkaa]

  • Selvitä missä sarakkeessa haettava teksti on. Teksti pitää olla tarkasti eli jos tekstin jälkeen olisi esimerkiksi välilyönti, se pitää sisällyttää sitaattien sisään. Vaihtoehtoisesti *-merkin lisääminen poistaa tämän tarkkuuden kuten "Haettavatek*"
  • VLOOKUP:n ensimmäinen parametri on haettava teksti. Seuraava on alue, joka sisältää sekä haettavan teksti että sen tekstin mikä halutaan noutaa soluun. Alla olevassa esimerkissä siis toiselta välilehdeltä sarakkeista A ja B haetaan tekstiä Haettavateksti ja kun se solu löytyy, noudetaan siitä oikealla olevan solun arvo.
=VLOOKUP("Haettavateksti";Välilehtinimi!A:B;2; FALSE)
=PHAKU("*haettavateksti*";A:B;2;EPÄTOSI)
  • Seuraavassa haetaan teksti, joka alkaa Haettavateks ja noudetaan kyseisen löydetyn solun arvo.
=VLOOKUP("Haettavateks*";Välilehtinimi!A:A;1; FALSE)

Tekstin muotoilu kaavassa[muokkaa]

=TEKSTI(TÄMÄ.PÄIVÄ();"PP.K.VVVV")
=TEXT(TODAY(),"DD/MM/YYYY")
Tuhaterotin: = TEKSTI(A1;"# #")

Tekstin yhdistäminen kahdesta solusta yhteen soluun[muokkaa]

  • Myös OpenOffice
    • =A1 & ", " & A2 (tässä esimerkissä väliin tulee pilkku)
    • =A1 & " " & A2 (tässä esimerkissä väliin tulee yksi väli)

Tiedostosta UTF-8 tai UTF-16[muokkaa]

https://help.surveygizmo.com/help/encode-an-excel-file-to-utf-8-or-utf-16

Tuhaterotin[muokkaa]

  • Tuhansien jälkeen ei ilmesty välilyöntiä (MacOS)
    • System Preferences > Language & Region > Advanced > Number separators: Grouping: Space > Käynnistä Excel uudestaan.

Tulostus[muokkaa]

Tulostettaessa eivät ilmesty solua pitemmät tekstit.

  • Solun formaatti/muoto saattaa olla väärin. Muuta esimerkiksi General

macOS[muokkaa]

  • Microsoft Excel: ei mahdollista.
  • OpenOffice (http://www.openoffice.org)
    • Save as type: Text CSV (.csv) > valitse Edit filter settings > Character set: Unicode (UTF-8)
  • LibreOffice (http://www.libreoffice.org): kyllä
  • Google Drive
    • Vedä hiirellä xls-tiedosto Google Driveen > File > Download as > Comma-separated values (.csv, current sheet).
  • Pääte

Tyhjien rivien poistaminen[muokkaa]

  1. Valitaan sarake > Find&Select > Go To Special... > Blanks > OK -> tyhjät rivit ovat valittuna
  2. Delete > Delete Sheet Rows

Valinnan mukaan lasketaan toisen solun arvo yhteen[muokkaa]

  • Esim. sarakkeessa A on hinta, B, C ja D-sarakkeissa valitaan X-merkillä ja E-sarakkeessa on tuotteen nimi. Nyt vain ne B, C ja D-sarakkeen hinnat lasketaan yhteen joissa on X-merkki. Kaava tehdään sarakkeille B, C ja D.
=SUMIF(B1:B100;"*";A1:A100)
  • Esim. sarakkeessa A on hinta, sarakkeessa B on tuotteen nimi ja soluun E1 kirjoitetaan tuotteen nimessä oleva sana. Ne rivit, joissa kyseinen sana on, lasketaan niiden hinnat yhteen.
=SUMIF(B1:B100,"*"&E1&"*",A1:A100)
https://exceljet.net/formula/sum-if-cell-contains-text-in-another-cell

Valintaruutu (checkbox)[muokkaa]

  • Lisäys
    • Kehitystyökalut > Lisää > Lomakeohjausobjektit > Painike. Vaihtoehtoisesti ActiveX-komponenteista.
  • Valintaruudun perusteella solun/solujen värjääminen
  • Esimerkiksi värjää solujen taustat punaisiksi ja kun valintaruutu valitaan, muuttuu se seuraavan kaavan johdosta vihreäksi.
  1. Valitse valintaruutu (ei solu)
  2. kirjoita valintaruudun kaavaksi kaavariville jokin samalla rivillä oleva vapaa solu tai toisen välilehden solu, esim. =K1 tai =välilehdennimi!A1
    1. Kyseiseen sarakkeeseen vahtuu TOSI tai EPÄTOSI sen mukaan onko valintaruutu valittuna tai ei.
  3. Valitse solu/solut, jotka esim. värjätään
  4. Aloitus > Ehdollinen muotoilu > Uusi sääntö... > Määritä kaavan avulla, mitkä solut muotoillaan
    1. Anna kaavaksi =JOS(K1=TOSI;EPÄTOSI;TOSI) jossa ensimmäin K1=TOSI on ehto ja sitten jos väite on tosi, vastaus on epätosi, muutoin tosi
      1. Muuta TOSI ja EPÄTOSI järjestystä sen mukaan miten haluat valinnan toimivan <-- tarkenna
      2. Huomaa, että vaikka käytetään vain K1, vaikuttaa kaava kaikkiin värjättyihin soluihin kullakin rivillä rivinumeronsa mukaan.
    2. Muotoile... > Täyttö > väri, esim. vihreä > OK
  • Kaavassa ja rivinvaihto päätteeksi: JOS(Välilehti!K1=EPÄTOSI;"Epätosi-teksti" & MERKKI(10);)
  • Valintaruudun arvon muuttaminen, VBA
Worksheets("Välilehdennimi").CheckBoxes("Valintaruutunimi").Value = True

Vienti[muokkaa]

Useat nettisovellukset antavat mahdollisuuden viedä tietokannoissa olevia tietoja Excel-taulukko muotoon. Taulukon avaaminen ei kuitenkaan onnistu välttämättä ongelmitta.

Ääkköset ja Macintosh[muokkaa]

Avaa Excel ja tuo tiedosto seuraavan toiminnon kautta: File / Import... / CSV file / Delimited, File origin Windows (ANSI)

Noudettu kohteesta ”https://wikikko.info/w3/index.php?title=Microsoft_Excel&oldid=7732”